plugins {
    id 'com.android.application'
}

android {
    namespace 'io.github.transui.android'
    compileSdk 35

    defaultConfig {
        applicationId 'io.github.transui.android'
        minSdk 26
        targetSdk 35
        versionCode 2
        versionName '0.1.1'

        testInstrumentationRunner 'android.test.InstrumentationTestRunner'

        externalNativeBuild {
            cmake {
                arguments '-DANDROID_STL=none'
            }
        }
    }

    signingConfigs {
        if (project.hasProperty('transuiKeystore')) {
            release {
                storeFile file(project.property('transuiKeystore'))
                storePassword project.property('transuiStorePassword')
                keyAlias project.property('transuiKeyAlias')
                keyPassword project.property('transuiKeyPassword')
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            if (project.hasProperty('transuiKeystore')) {
                signingConfig signingConfigs.release
            }
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }

    lint {
        abortOnError true
        checkReleaseBuilds true
        warningsAsErrors true
    }

    externalNativeBuild {
        cmake {
            path file('src/main/cpp/CMakeLists.txt')
        }
    }
}

dependencies {
    testImplementation 'junit:junit:4.13.2'
}